// t6Mage.txt
// Modified basicnpc.txt, used for the rebel mage in the Waterfall Cave.
// Has a dialog box that pops up when party first sees it.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. When the mage is killed, this flag is
//     set to equal 2.
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4,5 - SDF, makes sure that party only gets that intro dialog
//     once. (Set to one once party first sees the Adept)

begincreaturescript;

variables;

short i,target;

body;

beginstate INIT_STATE;
	set_aggression(ME,100);
	set_courage(ME,100);
	set_strategy(ME,1);

	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	reset_dialog();
	add_dialog_str(0,"Sorkeli falls to the ground, charms clinking madly. It seems that they weren't enough to keep her alive.",0);
	if(get_flag(3,6) == 1) {
		add_dialog_str(1,"With a degree of satisfaction, you realize that she won't be needing that graymold anymore.",0);
		toggle_quest(1,0);
		set_flag(3,6,2);
		}
	run_dialog(1);

	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),3);
break;

beginstate START_STATE; 
	//Intro text
	if((party_can_see_loc(my_loc_x(),my_loc_y()) == 1) && (get_flag(get_memory_cell(4),get_memory_cell(5)) == 0)) {
		reset_dialog();
		add_dialog_str(0,"A rebel mage comes into view, and you instantly recognize her heavy load of charms and bracelets. It's Sorkeli, the mage from Fort Galima!",0);
		add_dialog_str(1,"She smiles. _Welcome! Surely you've figured out what's going on by now, so I'm just going to cut to the chase._",0);
		add_dialog_Str(2,"_You see, there's nothing to be gained by working for an oppressive power like the Empire. But here... here, I can work to my fullest potential. And now, my work is to kill you._",0);
		if(get_flag(3,16) == 1)
			add_dialog_str(3,"Well, at least this explains where Sorkeli went.",0);
		run_dialog(1);
		set_flag(get_memory_cell(4),get_memory_cell(5),1);
		}

	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			do_attack();
			set_state(3);
			else 
				set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	else
		do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;